RouterOSv7においてv6プラス固定IP接続ができない

はじめまして。
最近RouterBOARDを触りはじめたばかりの新参者です。
まだ色々と勉強中ですが、今後ともどうぞよろしくお願いいたします。

質問内容
RouterOS 7にてv6プラス接続(固定IP)を試みているのですが、IPv4の通信が一切できません。
具体的には、ipipv6-tunnelを介してBR宛にパケットは送信されているものの、BRからパケットが帰ってきません。
ルータ(CCR2004)からBRのIPv6アドレス宛へpingは通っています。

ルータ側v6アドレスの設定を疑ったのですが、プロバイダから指定されているインターフェイスIDに正しく設定されている様です。
同一環境下において、別のルータ(Cisco 841M)ではv6プラスで接続できることを確認しております。

設定はRB-UG様にて公開されているこちらのものをほぼそのまま使用(Interfaceの割当等のみ修正)しており、firewallやmangleには設定例に記載されているもの以外は適用していません。

また、関連するトピックとして以下のポストを拝見したのですが、私のケースではipipv6トンネルは問題なくリンクアップしており、異なる状況であると考えています。

お手上げに近い状態ですので、何かお知恵を有しておられる方がおられましたら、お教えいただけると有難いです。
よろしくお願いします。

環境

  • ルータ:CCR2004-16G-2S+
  • HGW:PR-500KI
  • プロバイダ:IPQ IPv6+v4固定1IPサービス(v6プラス)

ネットワーク構成
NGN - HGW - CCR2004

テストしたRouterOS
以下のどのバージョンにおいても接続できませんでした
※CCR2004-16G-2S+はv7以降しか対応していない様で、動作報告があるv6にはダウングレードできません…

  • RouterOS 7.1.2
  • RouterOS 7.1.5
  • RouterOS 7.2

ご新規さん、歓迎します!

v6プラスでの接続が出来ないとのことですが、私の環境ではRouterOSv7で接続が出来ています。Arm64の環境を持っていないので、Tileだから上手くいっているのか判断できません。
お手数ですがexportコマンドで設定内容を貼り付けて頂くことは可能でしょうか?

環境

  • RouterOS 7.2
  • CCR1009-8G-1S-1S+
2 Likes

kometchtechさん、早速のご返信を有難うございます!

exportの出力を以下に添付させていただきます。設定後に何度かいじっているので、もしかすると余分な設定が入っているかもしれません。
※一部のIPアドレスは <設定値の説明> の形に置換しています

インターフェースの割当などの関係で量が多くなってしまいすみません…
HGWとの接続にはsfpplus1を割振り、それ以外のインターフェースはLAN側(bridge1)に割当しています。

お手隙の際にお目通しいただけると有難いです。
お手を煩わせますが、どうぞよろしくお願いいたします。

/interface bridge
add name=bridge1
/interface ethernet
set [ find default-name=sfp-sfpplus1 ] l2mtu=1460 mtu=1460
/interface ipipv6
add !keepalive local-address=<ISPの指定するインターフェースIDがセットされたv6アドレス> name=\
    ipipv6-v6plus remote-address=<BRのv6アドレス>
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip pool
add name=dhcp_pool1 ranges=192.168.1.2-192.168.1.254
/ip dhcp-server
add address-pool=dhcp_pool1 interface=bridge1 name=dhcp1
/port
set 0 name=serial0
set 1 name=serial1
/interface bridge port
add bridge=bridge1 interface=ether1
add bridge=bridge1 interface=ether2
add bridge=bridge1 interface=ether3
add bridge=bridge1 interface=ether4
add bridge=bridge1 interface=ether5
add bridge=bridge1 interface=ether6
add bridge=bridge1 interface=ether7
add bridge=bridge1 interface=ether8
add bridge=bridge1 interface=ether10
add bridge=bridge1 interface=ether11
add bridge=bridge1 interface=ether12
add bridge=bridge1 interface=ether13
add bridge=bridge1 interface=ether14
add bridge=bridge1 interface=ether15
add bridge=bridge1 interface=ether16
add bridge=bridge1 interface=sfp-sfpplus2
/interface ovpn-server server
set auth=sha1,md5
/ip address
add address=<ISPの指定するv4アドレス> interface=ipipv6-v6plus network=<ISPの指定するv4アドレス>
add address=192.168.1.1/24 interface=bridge1 network=192.168.1.0
/ip dhcp-server network
add address=192.168.1.0/24 gateway=192.168.1.1
/ip dns
set allow-remote-requests=yes cache-size=50000KiB max-concurrent-queries=200 \
    max-concurrent-tcp-sessions=40 servers=\
    8.8.8.8,8.8.4.4,2001:4860:4860::8888,2001:4860:4860::8844
/ip firewall mangle
add action=change-mss chain=forward comment="Clamp MSS to PMTU" disabled=yes \
    new-mss=clamp-to-pmtu passthrough=yes protocol=tcp tcp-flags=syn
/ip firewall nat
add action=masquerade chain=srcnat comment="NAT ipipv6" out-interface=\
    ipipv6-v6plus
/ip route
add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=ipipv6-v6plus \
    pref-src=0.0.0.0 routing-table=main scope=30 suppress-hw-offload=no \
    target-scope=10
/ipv6 address
add address=::1 comment="default gateway ipv6" from-pool=jpne interface=\
    bridge1
add address=<ISPの指定するインターフェースIDがセットされたv6アドレス> comment="default gateway ipv6" \
    interface=sfp-sfpplus1
/ipv6 dhcp-client
add add-default-route=yes interface=sfp-sfpplus1 pool-name=jpne request=\
    prefix
/ipv6 firewall mangle
add action=change-mss chain=forward comment="Clamp MSS to PMTU" disabled=yes \
    dst-prefix=::/0 new-mss=clamp-to-pmtu passthrough=yes protocol=tcp \
    src-prefix=::/0 tcp-flags=syn
/system clock
set time-zone-name=Asia/Tokyo
/tool sniffer
set filter-interface=sfp-sfpplus1
1 Like

ありがとうございます。明日にでも内容確認させていただきます。

また、Twitterの方に以下のような反応もありましたので、先に確認してみてはいかがでしょうか?(Ciscoでは問題ないとのことですが念のため

2 Likes

ザッと眺めていたのですが、以下のコマンドを確認していただけないでしょうか?

  • 以下のコマンドがなぜか無効化(disabled=yes)になっています。これがキモみたいなものなのでdisabled=noにするか、Winboxなどから有効化してください。
/ip firewall mangle
add action=change-mss chain=forward comment="Clamp MSS to PMTU" disabled=yes \
    new-mss=clamp-to-pmtu passthrough=yes protocol=tcp tcp-flags=syn
/ipv6 firewall mangle
add action=change-mss chain=forward comment="Clamp MSS to PMTU" disabled=yes \
    dst-prefix=::/0 new-mss=clamp-to-pmtu passthrough=yes protocol=tcp \
    src-prefix=::/0 tcp-flags=syn
  • 本件と直接関係がありませんが、DNSがWAN側からも問い合わせ可能な状態です。ブルートフォース攻撃に晒される可能性が高いので(実体験あり)filterでdropを追加するなどしてください。
/ip dns
set allow-remote-requests=yes cache-size=50000KiB max-concurrent-queries=200 \
    max-concurrent-tcp-sessions=40 servers=\
    8.8.8.8,8.8.4.4,2001:4860:4860::8888,2001:4860:4860::8844

これ(allow-remote-requests=yes)が危ない。v4/v6ともにfirewall/filterに追加する。

add action=drop chain=input comment="Block DNS" \
    dst-port=53 in-interface=<WANインターフェース> protocol=udp src-address-list=\
    !Allow_address
add action=drop chain=input  dst-port=53 \
    in-interface=<WANインターフェース> protocol=tcp src-address-list=!Allow_address

Allow_addressaddress-listからIPアドレスなどをまとめるパラメータを手元の環境で活用しているためです。

1 Like

夜分遅くまでご対応いただき、誠に有難うございます。
全く急ぎではございませんので、お手隙の際にご指導いただけると有難いです。

HGWのfirewallに関してですが、IPv6のfirewallは無効化しています。
検証の過程で何度かHGW側も初期化(初期化後にHGWのv6firewallは無効に設定)しているのですが、状況は変わらずです。

スクリーンショット 2022-04-07 23.25.40

※Cisco側に切り替えて再度確認してみたのですが、やはりCiscoでは接続できています。

mangleはたしか検証の途中で一度無効化したまま、元に戻すのを失念しておりました。
今、設定を戻して(disabled=no)確認しましたが、相変わらずBRからパケットが帰ってきません。

また、firewallの設定についてもご指導いただきありがとうございます。
とりあえず通信できる様にすることだけを考えて設定していた為、稚拙な設定を晒してしまい大変恥ずかしい限りです。

nukoさん、初めまして。

以前CCR2004(12S+のほう) で v6プラスを使用していた時の設定が手元にあるので、貼っていただいた設定と比較してみました。
今回のケースで参考になるか分からないのですが、ちょっと気になる違いについて2点お伝えしようと思います。

まず、私の設定ではIPIPv6インターフェースにMTUを設定していました。

/interface ipipv6
add !keepalive local-address=ひみつ mtu=1460 name=ipipv6-v6plus remote-address=ひみつ

もう一点、フレッツ回線に繋げたインターフェースをそのまま使用せず、ブリッジに所属させて、そのブリッジに対してIPv6のアドレス等を設定していました。

後者は、そうしないと何故か異常に低速になる問題を回避するためだったと記憶しているので、もし機種固有の問題だったり最近の版で直っていたりした場合は無意味かも知れません…。

2 Likes

そうそう、それと挙げていただいた過去のトピックを見て思い出したのですが、

PPPoEやIPIPはこちらが使用するインターフェース(のおそらくMACアドレス)が変わった場合に最長で30分ぐらい繋がらないことがありますね。

という経験則がありますので、設定や接続を変えた後は少し待ってみたほうが良いかもです。

2 Likes

うちはRB3011なのでちょっと設定は違うかもしれませんが
うちもひかり電話と併用しているので
普通にdhcp-clientでipv6が取れていてipv6で外に疎通が通るようになれば
ip-ipトンネルの設定は、単純にloca-addressを設定せずに

/interface ipipv6
add comment=“ds-lite” !keepalive local-address=:: name=ipipv6-tunnel1 remote-address=(AFTRのアドレス)

で問題なく通信できています…
うちは固定ではないので何とも言えませんが、v6plusでも固定だとlocal addressを見てるのかな…。

3 Likes

moogさん、はじめまして。
ご返信いただきありがとうございます。
RB-UGフォーラムの皆様にはご助力頂くばかりで恐縮です。

moogさんがご返信なさっている過去のトピック、大変参考にさせていただいております。

MTUの設定値ですが、mangle同様にこちらも私が検証の途中で消してしまった記憶があります(中途半端なconfigを貼ってしまい申し訳ありません…)
mtu=1460を再設定して確認してみたのですが、やはり状況に変化はございませんでした(今現在、設定適用から25分ほど経っている状態です)。

また、bridgeインターフェースを介した接続について貴重な情報をいただきありがとうございます。
明日の夕方以降と土日に腰を据えて検証させていただきます。

本件が機種固有の問題である可能性も考え始めています。
手元にあるCCRがCCR2004-16G-2S+ 1台のみで、機種依存問題なのか否かの切り分けが私一人ではできないのが大変もどかしいです。

2 Likes

Marshallさん、こんばんは。
コメントいただきありがとうございます。
また、Twitterの方でもありがとうございました。

少なくとも非固定IP環境下ではlocal-address無指定でも通信できるのですね。
他サイト様(たしか同じくv6プラス固定IP環境でした)にて、local-addressにISP指定のインターフェースIDを持つv6アドレスを与えないと通信できないと記載があったので、設定する必要があると思い込んでいたのですが、一度指定なしで試させていただきます。

IPoE接続をするのは今回が始めてなので勉強しながら進めており、もしかすると認識の一部が誤っているかもしれません。
また設定のミス等にお気付きであれば、忌憚なきご意見をお願いいたします。

MTUを確認いただきありがとうございます。

追加で気になった点なのですが、

/interface ethernet
set [ find default-name=sfp-sfpplus1 ] l2mtu=1460 mtu=1460

NGN自体のMTUは1500のはずですので、HGWに繋がる物理IFではMTUを設定せず(または1500設定)
トンネルIFの方で1460とするのが正しい気がします。

2 Likes

moogさん、ご返信いただき有難うございます。

追加でご指摘いただきましたインターフェースへのMTU設定についてですが、こちらも検証過程で変更したものがそのまま残っておりました…。

何度か初期化後に再設定をして接続を試みているのですが、未だ接続には至っておりません。
情報を頂いたBridgeインターフェース経由での接続も試してみたのですが、物理インターフェースを直接参照した場合と同様に接続できませんでした。

1G-12S+2XSと16G-2S+は同じプロセッサの様なので、1G-12S+2XSで動作報告があるのであれば16G-2S+でも接続できそうなのですが、苦戦しています…
CCR2004-1G-12S+2XS固有の問題なのか、複合的な問題なのかが未だ切り分けできていないので、もう少し検証をしてみます。

現状の設定を以下に記載させていただきます。
※OSはRouterOS v7.2です。

/interface bridge
add name=bridge-ngn
add name=bridge1

/interface ipipv6
add !keepalive local-address=<ISPの指定するインターフェースIDがセットされたv6アドレス> mtu=1460 name=\
    ipipv6-v6plus remote-address=<BRのv6アドレス>

/ip pool
add name=dhcp_pool1 ranges=192.168.1.2-192.168.1.254

/ip dhcp-server
add address-pool=dhcp_pool1 interface=bridge1 name=dhcp1

/interface bridge port
add bridge=bridge1 interface=ether1
add bridge=bridge1 interface=ether2
add bridge=bridge1 interface=ether3
add bridge=bridge1 interface=ether4
add bridge=bridge1 interface=ether5
add bridge=bridge1 interface=ether6
add bridge=bridge1 interface=ether7
add bridge=bridge1 interface=ether8
add bridge=bridge1 interface=ether10
add bridge=bridge1 interface=ether11
add bridge=bridge1 interface=ether12
add bridge=bridge1 interface=ether13
add bridge=bridge1 interface=ether14
add bridge=bridge1 interface=ether15
add bridge=bridge1 interface=ether16
add bridge=bridge1 interface=sfp-sfpplus2
add bridge=bridge-ngn interface=sfp-sfpplus1

/ip address
add address=192.168.1.1/24 interface=bridge1 network=192.168.1.0
add address=<ISPの指定するv4アドレス> interface=ipipv6-v6plus network=<ISPの指定するv4アドレス>

/ip dhcp-server network
add address=192.168.1.0/24 gateway=192.168.1.1

/ip firewall mangle
add action=change-mss chain=forward comment="Clamp MSS to PMTU" new-mss=\
    clamp-to-pmtu passthrough=yes protocol=tcp tcp-flags=syn

/ip firewall nat
add action=masquerade chain=srcnat comment="NAT ipipv6" out-interface=ipipv6-v6plus

/ip route
add check-gateway=ping distance=1 gateway=ipipv6-v6plus

/ipv6 route
add check-gateway=ping distance=1 dst-address=::/0 gateway=bridge-ngn

/ipv6 address
add address=<ISPの指定するインターフェースIDがセットされたv6アドレス>  comment="default gateway ipv6" from-pool=jpne \
    interface=bridge-ngn
add address=::1 comment="default gateway ipv6" from-pool=jpne interface=bridge1

/ipv6 dhcp-client
add add-default-route=yes interface=bridge-ngn pool-name=jpne request=prefix

/ipv6 firewall mangle
add action=change-mss chain=forward comment="Clamp MSS to PMTU" new-mss=\
    clamp-to-pmtu passthrough=yes protocol=tcp tcp-flags=syn
1 Like

@nuko

手元の環境と比較してみましたがさほど差は無いように見受けられます。
以下抜粋です。
(細かいところで違いはありますが・・・

  • HGWの受けのインターフェースはether5
/interface bridge
add arp=proxy-arp auto-mac=no name=bridge1

/interface ipipv6
add comment=v6_plus dscp=0 local-address=<int-ID-address> mtu=\
    1460 name=ipipv6-v6plus remote-address=<BR-address>

/interface bridge port
add bridge=bridge1 ingress-filtering=no interface=ether1
add bridge=bridge1 ingress-filtering=no interface=ether3
add bridge=bridge1 ingress-filtering=no interface=ether4
add bridge=bridge1 ingress-filtering=no interface=bonding1
add bridge=bridge1 ingress-filtering=no interface=ether2
add bridge=bridge1 ingress-filtering=no interface=ether6
add bridge=bridge1 ingress-filtering=no interface=ether8

/ip settings
set accept-source-route=yes icmp-rate-limit=100 max-neighbor-entries=8192 \
    rp-filter=loose tcp-syncookies=yes
	
/ipv6 settings
set accept-router-advertisements=yes max-neighbor-entries=8192

/ip address
add address=<ISPから払い出される固定IP> interface=ipipv6-v6plus network=<ISPから払い出される固定IP>
add address=192.168.88.1/24 interface=bridge1 network=192.168.88.0

/ip firewall mangle
add action=change-mss chain=forward comment="Clamp MSS to PMTU" new-mss=\
    clamp-to-pmtu passthrough=yes protocol=tcp tcp-flags=syn tcp-mss=\
    1433-65535

/ip firewall nat
add action=masquerade chain=srcnat comment="NAT ipipv6" out-interface=ipipv6-v6plus

/ip firewall service-port
set ftp disabled=yes
set tftp disabled=yes
set irc disabled=yes
set h323 disabled=yes
set sip disabled=yes
set udplite disabled=yes
set dccp disabled=yes
set sctp disabled=yes

/ip route
add check-gateway=bfd-multihop disabled=no distance=2 dst-address=0.0.0.0/0 \
    gateway=ipipv6-v6plus pref-src=0.0.0.0 routing-table=main scope=30 \
    suppress-hw-offload=no target-scope=10
	
/ipv6 route
add check-gateway=bfd-multihop disabled=no distance=1 dst-address=2000::/3 \
    gateway=<対向のリンクローカルアドレス>%ether5 routing-table=main scope=30 \
    target-scope=10
	

/ipv6 address
add address=::1/60 advertise=no comment="default gateway ipv6" \
    from-pool=JPNE interface=bridge1 no-dad=yes
add address=<ipipv6のインターフェースID> advertise=no comment=\
    IPIPv6-tunnel interface=ether5 no-dad=yes
	
/ipv6 dhcp-client
add interface=ether5 pool-name=JPNE pool-prefix-length=60 prefix-hint=\
    ::/64 request=prefix

/ipv6 firewall mangle
add action=change-mss chain=forward comment="Clamp MSS to PMTU" dst-prefix=\
    ::/0 new-mss=clamp-to-pmtu passthrough=yes protocol=tcp src-prefix=::/0 \
    tcp-flags=syn tcp-mss=1433-65535
add action=change-dscp chain=postrouting comment="NTT Flets rewrite qos" \
    dst-prefix=::/0 new-dscp=0 out-interface=ipipv6-v6plus passthrough=yes \
    src-prefix=::/0
add action=change-dscp chain=postrouting dst-prefix=::/0 new-dscp=0 \
    out-interface=ether5 passthrough=yes src-prefix=::/0

/system clock
set time-zone-name=Asia/Tokyo

今更ながらですがHGWの受け側のインターフェースはsfp-sfpplus1とのことですが、Etherへの変換は純正のS-RJ01とかで受けていますでしょうか? それとも社外品等でしょうか?

もしそうであればsfp-sfpplus1のインターフェースのspeedを1Gbpsなどに固定するなどすると状況は変わらないでしょうか?

2 Likes

ブリッジもダメでしたか…。

コンフィグを拝見して気になるところを指摘しているだけでは難しいかもしれず、
各レイヤーの疎通を一つずつ確認していくのが良いのかなと思っています。
以下にいくつか挙げてみます。

  • IPIPv6トンネルの通信が正しい送信元アドレスと宛先アドレスで行えているか
    (実は異なる送信元アドレスになってしまっていないか等)

    Winboxのターミナルにて

    /ipv6/firewall/connection/print detail where protocol=ipencap
    

    で、<ISPの指定するインターフェースIDがセットされたv6アドレス>と<BRのv6アドレス>が使われていることを確認。

  • 実際にそのアドレスを使用してBRとの通信が出来るのか

    /tool/ping src-address=<ISPの指定するインターフェースIDがセットされたv6アドレス> address=<BRのv6アドレス>
    

    で応答があることを確認。

  • ルーター自身からIPv4の通信はできるのか (NAT下の端末からでなく)

    /tool/ping src-address=<ISPの指定するv4アドレス> address=8.8.8.8 interface=ipipv6-v6plus
    

    で応答があるかどうか確認。


あとはブリッジやIPv4のFastPathやFastTrackを切ってみるとかですかね…。

2 Likes

kometchtechさん、こんばんは。
お手元の環境のコンフィグをお送りいただき、誠に有難うございます。

sfp-sfpplus1に接続しているSFP-RJ45モジュールはCiscoのSFP-GE-Tです。
sfp-sfpplus1speed=1Gbpsをセットしてみましたが、一向に変化はありません。
HGWとの接続インターフェースをRJ45のインターフェース(ether16)に変更したりもしてみたのですが、sfp-sfpplus1と状況は全く同じ(v6の通信は問題ないがipipv6 tunnelは通信できない)です。

一度、お送り頂いたコンフィグをほぼそのまま移植して動作を確認してみます。

moogさん、こんばんは。
何かとご指導いただき有難うございます。

現在の状況ですが、以下の様な状況です。
※FastPathを全て切った状態でテストしています

  • IPIPv6トンネルの通信が正しい送信元アドレスと宛先アドレスで行えているか
    src-addressreply-dst-addressには<ISPの指定するインターフェースIDがセットされたv6アドレス>、dst-addressreply-src-addressには<BRのv6アドレス>がセットされているので問題なさそうです。

  • 実際にそのアドレスを使用してBRとの通信が出来るのか
    正常にBRからecho replyが帰ってきます。

  • ルーター自身からIPv4の通信はできるのか
    8.8.8.8にpingを打ちましたがtimeoutします。

個人的にはipipv6トンネル周りに問題がありそうだと思っています。
ただ、Packet Snifferで見ている限りではBRに飛んでいるパケットに問題は無さそうなんです…(でもBRからパケットが帰ってこない状況から考えると、どこかに間違っている箇所があるはずなんですよね…)

Ciscoでは問題なくv6プラス接続ができているので、HGW〜ISP間には問題は無さそうだと思っています。一体どこで詰まっているのか…
皆様からのコメントを参考にさせていただきながら、引き続き検証してみます。

2 Likes

@nuko

確認ありがとうございます。

前投稿に「IPv4のpingを打った時にトンネル内へパケットが流れていること」を確認する項目が漏れていたのですが(申し訳ありません)

Packet Snifferで見ている限りではBRに飛んでいるパケットに問題は無さそう

ということですので、その確認は大丈夫そうですね。

CCR2004 → BRにトンネルのパケットを送るところまでは出来ているが応答がない
Cisco → 通信できる

そうなると、

  • CCR2004が送っているIPv6パケットにある何らかの問題によって、BR、フレッツ網、HGWのいずれかがパケットを落としている
  • CCR2004がトンネル内に流したIPv4のパケットに、BRやその先の機器がルーティング出来ない何かがある

みたいなことが考えられそうですね。

たとえばDSCP値で落とされていたりしないでしょうか。
NGNはこれが0でないとドロップするそうです。
(未指定のときのRouterOSの挙動がわからないのですが…)

/interface ipipv6
add dscp=0 !keepalive local-address=<ISPの指定するインターフェースIDがセットされたv6アドレス> mtu=1460 name=\
    ipipv6-v6plus remote-address=<BRのv6アドレス>

dscp=0、kometchtechさんの設定にも入っていますね。

1 Like

@moog @nuko

この辺りはここですね。

https://help.mikrotik.com/docs/display/ROS/IPIP

Set dscp value in IPIP header to a fixed value or inherit from dscp value taken from tunnelled traffic

このドキュメント通りならNGNで設定?されたDSCPを引き継いでいる状態ですね・・・

趣旨から外れた書き込みで申し訳ない。

2 Likes

Winboxで/tool/torchにて、ipipv6トンネルを指定したとき何も表示されないという状態で良いでしょうか?

また、/ip/routeの出力結果はどうでしょうか? 以下は手元の環境のものですが・・・

[[email protected]] > /ip/route/print 
Flags: D - DYNAMIC; A - ACTIVE; c, s, v, y - COPY
Columns: DST-ADDRESS, GATEWAY, DISTANCE
#     DST-ADDRESS        GATEWAY              DISTANCE
0  As 0.0.0.0/0          ipipv6-v6plus               1
  DAc <固定IPv4アドレス>    ipipv6-v6plus               0
  DAc 192.168.88.0/24   bridge1                     0

2 Likes